EJECT/INIT ROUTINE 100-120
/THIS ROUTINE IS CALLED AT THE BEGINNING OF PROGRAM EXECUTION.
/IT INITIALIZES THE LIST STORAGE, ETC.
AINIT, 0
  CLA
  TAD I AINIT /SET PARAMETERS
  DCA I AIPNT
  ISZ AINIT
  ISZ AIPNT
  ISZ AICNTR
  JMP .-5
  STA
  TAD I AINIT /GET PD LIST SIZE
  ISZ AINIT
  TAD FAINIT
  DCA I AIPTR
  TAD I AIPTR
  CIA
  DCA I AIMIN
  STA
  TAD I AIMIN
  DCA I AIMIN2
  STA /SET SUBLOC
  TAD AINIT
  DCA I AILOC
  TAD I AINIT /SKIP TO END
  SNA
  JMP .+5
  CIA
  DCA I AINIT
  ISZ AINIT
  JMP .-6
  DCA I AIWRK /CLEAR TABLE OF WORKING LOCATIONS
  ISZ AIWRK
  ISZ AIREF
  JMP .-3
  TAD AIEVAL /ADJUST VALUES
  DCA EVEVAL
  TAD AIERR
  DCA EVER2
  TAD AIPUSH /SET MACH LINKS
  DCA PUSH
  TAD AIPOP
  DCA POP
  TAD AIEV
  DCA EV
  TAD AITEST
  DCA TEST
  TAD AIDECB
  DCA CVBIN
  TAD AIBIND
  DCA CVDEC
  TAD EVBEG  /IF PD LIST OVERLAPS STORAGE AREA, ADJUST
  CIA        /  STORAGE SIZE.
  TAD EVLEN
  TAD I AIPTR
  IAC
  SMA
  JMP .+4
  CIA
  TAD EVLEN
  DCA EVLEN
  CLA
  TAD EVLEN  /SET ABS VAL TO NEXT LOWEST EVEN VAL IF NECESSARY.
  CIA
  RAR
  CLL RAL
  CIA
  DCA EVLEN
  TAD EVBEG  /SET VAL TO NEXT EVEN LOCATION IF NECESSARY.
  RAR
  SZL
  IAC
  CLL RAL
  DCA EVBEG
  JMP I AINIT
AIEVAL, LEVAL
AICNTR, -4
AIERR, ERR
AIPNT, EVBEG
AIWRK, WORK
AIREF, WORK-ENDWRK
AIPUSH, LPUSH
AIPOP, LPOP
AIEV, EVAL2
AITEST, ATEST
AIDECB, DECBIN
AIBIND, BINDEC
FAINIT, ENDINT
AILOC, EVLOC
AIPTR, STPTR
AIMIN, STMIN
AIMIN2,COMIN
PAGE
ENDINT=.
/Commented out by VRS: *.-1